Ramp headcombs

15.10.2020, 16:23 - Autor: Mark B.
Good headcombs make your live easier but what if you don't get the right one e.g. for very new drives. Right, you make your own!

This OpenSCAD-file is for the more modern drives with ramps and you can customize the headcombs to you liking in with, length of the handle or thikness of the back. (see pictures)

Just change the parameters on the top of the file and then select on the very bottom Comb2D(); or Comb3D(); be commenting the unwanted one out and render the file.

Further will be in the near future a database with the right parameters for specific drives - so you just need to search the model and download the fitting SCAD-file.

Before you consider to start I would recommand to read the fabriaction-tipps. With a few cheap and basic machines you can make your own headcombs.

Source

$fn = 128;

/////////////////////////////////////////////////////////////////
// Parameters for the model in mm
/////////////////////////////////////////////////////////////////
heads            = 6;   // no. of heads
handle           = 0;   // length of handle
width            = 3.0; // width of comb for 3D printing
thickness        = 5.5; // thikness of comb-back

spacer_height    = 2.10; // hight of the spacer
spacer_peak      = 0.07; // hight of the peak to overcome
spacer_distance  = 1.40; // spacing between spacers (MIN. ==  spacer_peak * 2 + 0.3 !!!)
spacer_length    = 2.60; // length of resting-area for head


/////////////////////////////////////////////////////////////////
// Calculations for the model
// Don't change them
/////////////////////////////////////////////////////////////////
spacers = ceil(heads / 2);
height  = handle + (spacer_height + spacer_distance) * spacers + 0.5;


/////////////////////////////////////////////////////////////////
// Fixed Parameters
// Don't change them
/////////////////////////////////////////////////////////////////
phase = 1.2;


/////////////////////////////////////////////////////////////////
// Spacer model 2D for CNC
/////////////////////////////////////////////////////////////////
module Spacer2D(){
    square([spacer_length - 0.1, spacer_height]);
    
    hull(){
        translate([spacer_length - 0.1, 0]) 
          square([0.1, spacer_height]); 
        
        translate([spacer_length + 0.6, -spacer_peak]) 
          square([0.1, spacer_height + spacer_peak * 2]);
        
        translate([spacer_length + 2.4, (spacer_height) / 2 - 0.1]) 
          square([0.1, 0.2]);
    }
}


/////////////////////////////////////////////////////////////////
// Comb model 2D for CNC
/////////////////////////////////////////////////////////////////
module Comb2D(){
    difference(){
        translate([-thickness, 0]) square([thickness, height]);
        
        lb = sqrt(phase * phase / 2);// - phase/2 * phase/2);
        #translate([-thickness - phase/2, 0]) rotate([0, 0, -45]) square([lb, lb]);
        translate([-thickness - phase/2, height]) rotate([0, 0, -45]) square([lb, lb]);
        translate([-phase/2, height]) rotate([0, 0, -45]) square([lb, lb]);
    }

    // Add spacers in position 
    for(i = [0 : 1 : spacers - 1]){
        z_pos = i * (spacer_height + spacer_distance) + 0.5;
        translate([0, z_pos]) 
          Spacer2D();
    }
}


/////////////////////////////////////////////////////////////////
// Comb model 3D for printing
/////////////////////////////////////////////////////////////////
module Comb3D(){
    linear_extrude(width) Comb2D();
}


/////////////////////////////////////////////////////////////////
// Display model
/////////////////////////////////////////////////////////////////
Comb2D();
//Comb3D();


Download OpenSCAD file






System requrements:

Windows, OSX or Linux with


List of known parameters (partially untested)


2.5" Headcombs

Model *1) Heads Spacer height Spacer distance Compatible drives
1.1 2 1.20 mm 1.30 mm Seagate Momentus thin, WD Hubble, Hubble LT, Makalu, Aries
2.1 2 1.30 mm 1.30 mm WD Palmer, Hitachi / HGST 5450A7, 5432A7, 7232A7, 7250A7
3.1 2 1.40 mm 1.30 mm Toshiba MQ01ABD, MQ01ABF
4.1 2 1.50 mm 1.30 mm ???
1.2 4 1.30 mm 1.10 mm ???
2.2 4 1.20 mm 1.20 mm Hitachi / HGST 5410G9, 5410A9, 5425K9, 7210A9
3.2 4 0.90 mm 1.40 mm Hitachi / HGST 5410A7
4.2 4 1.20 mm 1.10 mm WD Zephyr, Mariner, Denali, Shasta, Shasta 2d, Mckinley, Toshiba MK-5056GSY, Hitachi 5432L9, 5475A9, MQ01ABD with 4 heads
5.2 4 1.10 mm 1.20 mm WD Firebird, FBlite, Esprit
6.2 4 1.10 mm 1.30 mm Seagate M8, M8E, M8BP2, M7S2, Hitachi 5432L9
7.2 4 0.90 mm 1.30 mm WD Charger
1.3 6 1.10 mm 0.90 mm Samsung / Seagate M9, M9T, M9TU, M9TВ
2.3 6 1.20 mm 1.40 mm WD Helios, Seagate Savvio, Samsung Spinpoint MT2
3.3 6 1.40 mm 1.40 mm Seagate Sentosa
1.4 8 1.10 mm 1.40 mm Toshiba MQ01UBB, MQ03UBB
2.4 8 1.20 mm 1.30 mm WD Shrek, Shrek LT
3.4 8 1.20 mm 1.20 mm Seagate Freeplay
1.5 10 1.00 mm 1.30 mm WD Pebble, SpyGlass
2.5 10 1.00 mm 1.00 mm Seagate M10TDP, M11

*1) The way to read it is: model number . number of spikes - e.g.: 2.3 is model 2 with 3 spikes

3.5" Headcombs

Model Heads Spacer height Spacer distance Compatible HDDs
c 2 1.80 mm 1.80 mm Seagate Grenada, Bogart, Bacall, Pharaoh, Fujitsu MBA3073RC
b 4 1.70 mm 1.80 mm Seagate Grenada, Bogart, Bacall, Pharaoh, Muskie, Hitachi Deskstar 180GXP
e 6 1.60 mm 1.80 mm Seagate Grenada, Bogart, Bacall, Pharaoh
h 8 1.60 mm 1.70 mm Seagate Grenada, Bogart, Bacall, Pharaoh, Lombard
k 2 2.10 mm 1.70 mm WD Tahoe, Tahoe LT, Tressels, Dragflly, Sequoia, Draco, Excelstor Callisto, Toshiba DT01ACA, Seagate Grenada
n 4 2.10 mm 2.10 mm WD Tahoe, Hitachi Deskstar 7K1000.C
v 6 2.30 mm 1.50 mm WD Kermit, Sadle G6, Tornado, Atlantis, DragFly, Diablo3D, DELL WD RE3, Hitachi Deskstar 7K3000, Toshiba DT01ACA
u 10 1.50 mm 1.50 mm WD Vivaldi, REMBRANDT
x 10 2.00 mm 1.40 mm Seagate Megalodon
y 2 2.30 mm 1.20 mm WD Sumt Re, Sequoia PMR, Hitachi Cinemastar 5K1000, Deskstar 180GXP